cmake_minimum_required(VERSION 3.10)
project(Demo VERSION 1.0.0)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

include_directories(
    /usr/include/opencv4
)

find_library(AIDCV_LIBRARY NAMES aidcv)
find_path(AIDCV_INCLUDE_DIR NAMES aidlux/aidcv/aidcv.hpp)
if(AIDCV_LIBRARY AND AIDCV_INCLUDE_DIR)
    set(HAVE_AIDCV ON)
    message(STATUS "Found aidcv: ${AIDCV_LIBRARY} (include: ${AIDCV_INCLUDE_DIR}), use PillowResize for resize")
else()
    set(HAVE_AIDCV OFF)
    message(STATUS "libaidcv not found (lib: ${AIDCV_LIBRARY}), use OpenCV cv::resize")
endif()

set(link_libs   aidgen
                opencv_core
                opencv_imgproc
                opencv_imgcodecs
                pthread
)

function(aidgen_add_test name)
    cmake_parse_arguments(ARG "WITH_AIDLITE;WITH_AIDCV" "" "SOURCES" ${ARGN})

    if(NOT ARG_SOURCES)
        message(FATAL_ERROR "aidgen_add_test(${name}): SOURCES 不能为空")
    endif()

    add_executable(${name} ${ARG_SOURCES})
    target_link_libraries(${name} ${link_libs})
    set_target_properties(${name} PROPERTIES
        RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}"
    )

    if(ARG_WITH_AIDLITE)
        target_link_libraries(${name} aidlite)
    endif()

    if(ARG_WITH_AIDCV AND HAVE_AIDCV)
        target_compile_definitions(${name} PRIVATE HAVE_AIDCV)
        target_include_directories(${name} PRIVATE ${AIDCV_INCLUDE_DIR})
        target_link_libraries(${name} aidcv)
    endif()
endfunction()

aidgen_add_test(test_t2t
    SOURCES test_aidgen_t2t.cpp)

aidgen_add_test(test_t2e
    SOURCES test_aidgen_t2e.cpp)

aidgen_add_test(test_qwen25vl
    SOURCES qwen25vl_test.cpp qwen25vl_image_process.cpp
    WITH_AIDLITE WITH_AIDCV)

aidgen_add_test(test_qwen3vl
    SOURCES qwen3vl_test.cpp qwen3vl_image_process.cpp
    WITH_AIDLITE WITH_AIDCV)

aidgen_add_test(test_qwen35vl
    SOURCES qwen35vl_test.cpp qwen35vl_image_process.cpp
    WITH_AIDLITE WITH_AIDCV)

aidgen_add_test(test_locateanything
    SOURCES locateanything_test.cpp locateanything_image_process.cpp
    WITH_AIDLITE WITH_AIDCV)

aidgen_add_test(test_internvl3
    SOURCES internvl3_test.cpp internvl3_image_process.cpp
    WITH_AIDLITE WITH_AIDCV)

aidgen_add_test(test_mage
    SOURCES magevl_test.cpp magevl_image_process.cpp
    WITH_AIDLITE WITH_AIDCV)